How can substitute() operate on a whole buffer?

Question

In normal usage :%s/A/B/g is a simple way to substitute a pattern across the entire buffer. However the command mode implementation of :substitute is subject to many user configurable variables and as such linters rightfully complain about it's usage in scripts.

I'm trying to use call substitute() instead since this is a documented best practice in scripts. Using it against a string is easy, but I can't figure out how to make it operate on a buffer. I seem to be able to to call setline('1', substitute(getline('1'), 'A', 'B', '')) to change one line at a time, but it doesn't work across a whole buffer.

What is the correct robust way to run a substitution across a whole buffer from a script or plugin?

Answer 1

The only problems I see with :substitute are:

• it messes a few registers
• we may have to be wary of the separator character used that'll need to be escaped
• its behaviour depends on 'magic' option (as well as substitute()'s one)

If you really want to operate on the whole buffer without :s, you could also use the following oneliner (that'll be more efficient than any loop)

call setline(1, map(getline(1,'$'), {k,v -> substitute(v, 'PATTERN', 'REPLACEMENT', FLAGS)}))

Answer 2

since this is documented best-practice in scripts

Documented where?

In vimscript (in which plugins are written), every "statement" is an Ex command, you can do

function MyFunc() abort
  %substitute/pattern/repl/g
endfunction

or whatever it is you're trying to do. This is in fact the simplest mechanism. You can add modifiers (keepjumps, etc.) to the command, or build it up programmatically, or any of the usual things. But don't make this painful by trying to use a substitute() function—that works on a single string—on the entire buffer.

---

If you insist...

You could do a Schwarzian transform from list of lines to line, substitute, and reverse.

Or you could loop

for line in range(0, line('$'))
  call setline(line, substitute(getline(line), 'A', 'B', ''))
endfor

But, why?

---

See also this Q&A

Answer 3

One way could be using regular for loop:

let idx = 1
for line in getbufline(bufnr('%'), 1, "$")
    call setline(idx, substitute(line, 'A', 'B', 'g'))
    let idx += 1
endfor

or

for line in range(0, line('$'))
  call setline(line, substitute(getline(line), 'A', 'B', 'g'))
endfor

which is pretty obvious.

Another one could be:

let buflines = getbufline(bufnr('%'), 1, "$")
%delete _
call append(0, map(buflines, {_, line -> substitute(line, 'A', 'B', 'g')}))
$delete _

It takes all current buffer lines, then deletes whole buffer and appends transformed by map saved buffer lines. With append you going to have additional newline at the end, so the last line deletes it.

There probably more ways to do it, not sure.

But!

I would still go with regular %s// command. Remember you can set it up the way you like using :execute command:

let pattern = 'A'
let sub = 'B'
execute "%s/" . pattern . "/" . sub . "/g"

Note, instead of dot concatenation ppl suggest using printf.