How to reverse the order of lines?

Question

How can I reverse the order of lines so that the first line appears at the end and the last line appears first? (Could be all the lines in a buffer, an address range, or a linewise visual mode selection.)

I'd like to transform

rat
ox
tiger
⋮
dog
pig

into

pig
dog
⋮
tiger
ox
rat

without resorting to an external command such as tac.

Answer 1

The power of global will work here:

:g/^/exe "normal ddggP"

Or, more simply (thanks @tommcdo)

:g/^/move 0

The first will match every line and for each line, delete it and paste it to the top of the file. As it moves through the file, it reverses the text.

The second similarly matches every line and moves it to the top of the file.

Note: Both of these work on the whole file and will not apply correctly to reversing a subset of the lines. See Ingo Karkat's answer for a solution that works within a range.

Description:

g global command
/^/ match any line that has a beginning (i.e. all lines)
exe execute the following string
"normal perform normal mode commands
dd delete line
gg move to top of file
P paste above current position

move 0 moves the current line to below line 0 (which puts it at position 1, or the first line of the file)

Answer 2

This one-liner (for your ~/.vimrc) defines a :Reverse command; you can also use the :global part directly, but the syntax of the :move (which iteratively shifts the lines to before the start of the range, thereby reversing it) isn't easy to memorize:

:command! -bar -range=% Reverse <line1>,<line2>global/^/m<line1>-1

Answer 3

Pure Vim:

:g/^/m0

Explanation:

According to :help multi-repeat, :g and its cousin :v work in a two-pass manner.

The first pass of :g marks every line matching {pattern}, while the second pass (apparently performed starting at the file's beginning and proceeding to the end) performs the [cmd]. The above use of :g takes advantage of the order the lines are processed in (which is probably okay, though probably not technically guaranteed).

It works by first marking every line, then moving the first marked line to the top of the file, then moving the second to the top of the file (above the line moved previously), then the third marked line (again above the previously moved line), and so on until the last line in the file is moved to the top, effectively reversing the file.

Note that if :g processed lines in any order other than from top to bottom, this command would not work.

Source: Reverse all lines and Power of g at vim wikia.

Few examples using external commands:

• tac (part of GNU coreutils - cat reversed):

  :%!tac                                                                                                                                                                                                                                                              
  

• tail on BSD/OSX (not POSIX-compliant):

  :%!tail -r
  

  -r The -r option causes the input to be displayed in reverse order, by line.

  Check: man tar for more details.

For more ideas, see:

• How can I reverse the order of lines in a file? at stackoverflow SE
• How to reverse lines of a text file? at stackoverflow SE
• How can I print lines from file backwards (without using “tac”)? at Unix SE

Answer 4

Per the Vim Documentation usr_12.txt - Clever Tricks

12.4 Reverse line order

The :global command can be combined with the :move command to move all the lines before the first line, resulting in a reversed file. The command is:

:global/^/m 0

Abbreviated:

:g/^/m 0

The ^ regular expression matches the beginning of the line (even if the line is blank). The :move command moves the matching line to after the mythical zeroth line, so the current matching line becomes the first line of the file. As the :global command is not confused by the changing line numbering, :global proceeds to match all remaining lines of the file and puts each as the first.

This also works on a range of lines. First move to above the first line and mark it with mt. Then move the cursor to the last line in the range and type:

:'t+1,.g/^/m 't

Answer 5

In the spirit of functional VimL:

:call setline(1, reverse(getline(1, line('$'))))

• getline(1, line('$')) returns a list of all the lines in the buffer. '$' is a special argument for line() which indicates the last line in the buffer.
• reverse(...) reverses the input list, in-place. One would need to use reverse(copy(...)) if the input list shouldn't be modified.
• setline(1, ...) replaces the specified line with the second argument. When the second argument is a list, the same number of lines as the length of the list is replaced with the content of the list.

If you like, you can also define a command which takes a range (default % entire buffer)

:command! -bar -range=% Reverse call setline(<line1>, reverse(getline(<line1>, <line2>)))

Answer 6

Using relative numbers. Paragraph starts at line 13 and spams more 4 lines

 :13,13+4g/^/m12