Using visual selection or register for search and replace

Question

Is there a way to use a register or visual selection for search and replace? I have some longer sequence of words that are used repeatedly in my script. I want to replace them all but want to avoid typing a long sentence in a command line. If I can select them in visual mode or yank them in a buffer, and utilize it in replacement, it makes my life a lot easier.

i.e. Instead of doing something like,

:%s/Some really long word sequence that Id0n+wanna type /replacement sentence/g

I am imagining something like.

:%s/selected/replacement in a register/g

Answer 1

One possible solution is to use what I call register recall: on the :-command line, Ctrl-r followed by any of the registers (the named ones, like a or 3, or the others, such as - or ") will insert the contents of said register.

(This works in insert mode as well.)

So you could

1. Yank the text
2. Substitute with :%s/<C-r>"/replacement/g

It’s also interesting to note that this works on searches, too, so you could

1. Yank the text
2. Search: /<C-r>"
3. Verify that you get the matches you want, or further refine the search pattern
4. Substitute using the last pattern: :%s//replacement/g

A further refinement is to yank the replacement and do

:%s//<C-r>"/g

Answer 2

I use the following plugin to search for visually selected text:

function! VisualSelection()
    " Save register content and type.
    let old_reg     = getreg('"')
    let old_regmode = getregtype('"')

    " Calling this function has ended visual mode, so it must be started
    " again before the selection can be yanked into the unnamed register.
    normal! gvy
    let selection = @"

    " Restore register content and type.
    call setreg('"', old_reg, old_regmode)

    return selection
endfunction

function! Escaped(text)
    call inputsave()
    let result = escape(a:text, '\\/.*$^~[]')
    let result = substitute(result, "\n$", "", "")
    let result = substitute(result, "\n", '\\n', "g")
    call inputrestore()
    return result
endfunction

xnoremap <silent> <unique> * :<C-U><cr>/<C-R><C-R>=Escaped(VisualSelection())<cr><cr>
xnoremap <silent> <unique> # :<C-U><cr>?<C-R><C-R>=Escaped(VisualSelection())<cr><cr>

This overrides the default behavior of * and + which would extend the visual selection to the next occurrence of the word under the cursor.

For replacement you can define a third mapping which creates a substitute command for the whole buffer and prefills the search text with the visually selected text:

xnoremap <silent> <unique> g* :<C-U>%s/<C-R><C-R>=Escaped(VisualSelection()) . '/'<cr>