How to search in all registers

Question

Is there a nondestructive way to search a pattern in all registers, like redirecting :reg to some register and then paste it to a new buffer and perform the search there?

Answer 1

You can have the list of registers that match a pattern with:

:let regs=split('abcdefghijklmnopqrstuvwxyz0123456789/-".', '\zs')

:echo filter(regs, 'getreg(v:val) =~ "the_pattern"')

Or if you really prefer to paste all registers into a buffer in order to search interactively (and not programmatically) -- I leave the creation of scratch buffer out

:let regs=split('abcdefghijklmnopqrstuvwxyz0123456789/-".', '\zs')
:call map(regs, '"\"".v:val. "  ".getreg(v:val)')
:put=regs

" or, if neither the noise nor the joined lines bother you
put=execute('registers')

Answer 2

Just create a new unnamed buffer and then put the output of :reg into it with

:enew
:put =execute('reg')

Note that the output of :reg is truncated to terminal width.

Where = is the "expression register" and execute('reg') is the expression. See :help @=.

The function execute() executes a command and returns the output as string. See :help execute().

---

Or, to show the power of Vim:

command -nargs=1 RegSearch echo join(filter(split(execute('reg'), "\n"), {i, v -> v =~ <q-args>}), "\n")

Inner-to-outer:

• execute('reg') is already known
• split(..., "\n") split into a list of lines
• filter(..., {i, v -> v =~ <q-args>}) only keep those line that match the commands argument (see :help <q-args> and :help lambda)
• join(..., "\n") join the kept list elements into a string separated by newlines.

Then use it like this:

:RegSearch <searchterm>

Searchterm is a regular expression. If it contains whitespaces, they have to be escaped with a backslash.

_{I love it when it is doable on one line :-). And then Christian writes a comment ... :-/ He is right.}

Answer 3

Here is a gist from romainl

Here is my tweaked version of the gist.

" Redirect the output of a Vim or external command into a scratch buffer
command! -nargs=1 Redir
            \ tabnew |
            \ setlocal nobuflisted buftype=nofile bufhidden=wipe noswapfile |
            \ call setline(1, split(execute(<q-args>), "\n"))

Now, you can do :Redir reg to open a new tabpage with output of :reg. Then do what you gotta do.