Simple modification of behavior of Home, End keys

Question

I'm completely new to Vim scripting, so forgive me if this may seem trivial, but I would like to modify the Behavior of the Home and End keys such that, if the cursor is somewhere between the first and last non-blank character of the line, they would take me to the first or last non-blank character, respectively. However, if the cursor is already sitting on the first or last character of the line, they go to the first or last non-blank character on the next line, respectively. I think I know some bits and pieces of how to do this, but I have trouble figuring out how to query for the two conditions (cursor on first or last character of the line). Seeing a complete solution would help me learn good coding style also. Thanks!

Answer 1

That's odd, I was quite sure this question was a duplicate, but I cannot find the other Q/A.

Anyway. This is how I proceed:

inoremap <silent> <Home> <c-o>@=<SID>HomeLikeVCpp()<cr>
nnoremap <silent> <Home> @=<SID>HomeLikeVCpp()<cr>
vnoremap <silent> <Home> @=<SID>HomeLikeVCpp()<cr>

inoremap <silent> <End> <c-\><c-n>@=<SID>EndLikeVCpp()<cr>a
nnoremap <silent> <End> @=<SID>EndLikeVCpp()<cr>
vnoremap <silent> <End> @=<SID>EndLikeVCpp()<cr>

function! s:HomeLikeVCpp()
  let ll = strpart(getline('.'), -1, col('.'))
  if ll =~ '^\s\+$' | return '0'
  else              | return '^'
  endif
endfunction


function! s:EndLikeVCpp()
  let l = strpart(getline('.'), col('.')-1)
  let ll = match(l, '^\S\s*$')

  if getline('.') =~ '^\s*$'
    if col('.') + (mode()!='v') == col('$') | return 'g_'
    else                                    | return '$'
    endif
  else
    if ll >= 0 | return '$'
    else       | return 'g_'
    endif
  endif
endfunction

Nowadays, I'd rewrite it with :map-<expr>.

Answer 2

Thanks everybody for their pointers. Here is my solution, in case it's helpful to someone:

" Enhanced Home and End keys                           
inoremap <silent> <Home> <c-o>@=<SID>ExtHome()<cr>i    
nnoremap <silent> <Home> @=<SID>ExtHome()<cr>          
vnoremap <silent> <Home> @=<SID>ExtHome()<cr>          

inoremap <silent> <End> <c-\><c-n>@=<SID>ExtEnd()<cr>a 
nnoremap <silent> <End> @=<SID>ExtEnd()<cr>            
vnoremap <silent> <End> @=<SID>ExtEnd()<cr>            

function! s:ExtHome()                                  
   if col('.')=='1'  | return 'j'                      
   else              | return '0'                      
   endif                                               
endfunction                                            

function! s:ExtEnd()                                   
   if strlen(getline('.')) == 0            | return 'j'
   elseif strlen(getline('.')) == col('.') | return 'j'
   else                                    | return '$'
   endif                                               
endfunction