How can I tell if I'm in the command window?

Question

Extremely related to this except the answer there doesn't work

I get the following error when entering command-line editing mode q: or Ctrl-F (when already in command mode)

Error detected while processing CursorHold Auto commands for "*":
E11: Invalid in command-line window; <CR> executes, CTRL-C quits:  checktime | endif

The relevant section of my .vimrc is

"automatically reload file when changes detected
set autoread "this doesn't work on it's own!

"https://unix.stackexchange.com/questions/149209/refresh-changed-content-of-file-opened-in-vim/383044#383044
"on these events, any filename... and not in command mode then check files for changes
autocmd FocusGained,BufEnter,CursorHold,CursorHoldI * if mode() != 'c' | checktime | endif

" Notification after file change
autocmd FileChangedShellPost *
  \ echohl WarningMsg | echo "File changed on disk. Buffer reloaded." | echohl None

So my question is how do I detect that I'm in the command-line window and stop that command from running there?

After a bit of reading :h command-line I tried replacing the condition with

if mode() != 'c' && getcmdwintype() == ''

but I'm still seeing the same issue.

Answer 1

Based on Luc's help I ended up going with this:

autocmd FocusGained,BufEnter,CursorHold,CursorHoldI * if !bufexists("[Command Line]") | checktime | endif

The reason this works is that the Command Line window is fairly modal so you can't have one accidentally open in the background - you will only get that buffer if you are actively editing in the command-line-window

The only caveat here is that if you save a buffer with that name, which I did accidentally at some point when messing around with this stuff - in which case the Command line window complains when it gets opened and instead gets named "[Scratch]" or something.

It's also worth noting that you should probably have something like this at the very top of your .vimrc as autocmds are just added to a list and if you are developing them you can end up with your old ones kicking around.

"clear out previous autocmds to stop them being duplicated when resourcing
"this file
autocmd!

I also learned you can list all autocmds by doing :autocmd and list for a specific event like:

:autocmd CursorHold
--- Auto-Commands ---
ALECursorGroup  CursorHold
    *         call ale#cursor#EchoCursorWarningWithDelay()
CursorHold
    *         if !bufexists("[Command Line]") | checktime | endif
Press ENTER or type command to continue

Answer 2

bufname('%') returns "[Command Line]" in my case. I don't know if there is another information elsewhere.

You could also listen for CmdwinEnter and CmdwinLeave events and maintain an internal state that'll tell you in which mode you are.

EDIT: Here is what I would do. Note, this is completely untested. This may not work.

" ==== file: autoload/cmdlinewindow.vim
" Initialize to 0, keep the current state if the script is reloaded
let s:is_opened = get(s:, 'is_opened', 0)

function! cmdlinewindow#_enter() abort
    call lh#assert#false(s:is_opened)
    let s:is_opened = 1
endfunction

function! cmdlinewindow#_leave() abort
    call lh#assert#true(s:is_opened)
    let s:is_opened = 0
endfunction

function! cmdlinewindow#is_opened()
    return s:is_opened
endfunction

" ==== file: plugin/cmdlinewindow.vim
aug WatchCmdLineWindow
    au!
    au CmdwinEnter * call cmdlinewindow#_enter()
    au CmdwinLeave * call cmdlinewindow#_leave()
aug END

Then, from elsewhere, you'd just have to check cmdlinewindow#is_opened() result.

NB: lh#assert#...() comes from my vim script library. They are not needed, yet they state in which state I expect to be when calling these functions.

Answer 3

I am having the same issue as you. There are some discussions here and here. It seems that we can use getcmdwintype() to check if we are in command line window. Here is my working setting:

augroup auto_read
    autocmd!
    autocmd FocusGained,BufEnter,CursorHold,CursorHoldI *
                \ if mode() == 'n' && getcmdwintype() == '' | checktime | endif
augroup END

Answer 4

For posterity: Turns out, additionally to the mentioned approaches (which would qualify as hacks in my book) you can simply use getcmdwintype(). Credits to user micbou from the Youcompleteme maintainers. Docs:

getcmdwintype()
        Return the current |command-line-window| type. Possible return
        values are the same as |getcmdtype()|. Returns an empty string
        when not in the command-line window.