Why does Rename fails with Python files if there is no trailing space?

Question

:Rename (from vim-rename) fails with Python files in my current set up with the following error:

line   46:
E486: Pattern not found: \s\+$

if the file does not contain trailing whitespaces in at least one line, leading to the file being duplicated (with the new name and the old one).

Using the following file helloworld.py (note there are no trailing whitespaces):

print("Hello, world!")

If I attempt to use :Rename new_name.py it will spew out the previously-mentioned error, and I'll end up with two files (helloworld.py and new_name.py). If, however, I add whitespaces at the end of the line, the renaming will succeed and the trailing whitespaces are automatically removed.

This seems to be due to some sort of conflict between vim-rename and python-mode, since it only happens with Python files.

After debugging what happens on a write with :debug write, I can see that pymode#trim_whitespaces() is invoked by default by python-mode. If I disable it by let g:pymode_trim_whitespaces=0, the problem with vim-rename goes away. However, automatic trimming of trailing whitespaces is a feature I don't want to lose.

My questions, in order of importance:

1. How can I fix this so that I can rename files and keep the automatic trimming of whitespaces?
2. Why is the non-existence of whitespaces causing rename to fail?

I would prefer to keep vim-rename, although I'm willing to switch it for a more robust plugin if necessary. Fixing the code in vim-rename manually would also be acceptable.

If it is of any use, this is my complete vimrc file.

Answer 1

I'm not clear on why the problem occurs — the line in pymode#trim_whitespaces() that is triggering the error includes a silent! so the error should be ignored. You could maybe try appending an e flag to ignore the errors more specifically:

silent! %s/\s\+$//e

If that works, you should probably report it to the author of python-mode.

However, I'm not too motivated to dig any deeper into what's going wrong, because there's a very simple workaround, which is to write a new command which turns off "trim whitespaces" before running the rename and then restores it afterwards.

function! MyRename(new_name, bang)
  if exists("g:pymode_trim_whitespaces")
    let orig_trim_whitespaces = g:pymode_trim_whitespaces
  endif
  let g:pymode_trim_whitespaces = 0

  execute "Rename" . a:bang . " " . a:new_name

  if exists("orig_trim_whitespaces")
    let g:pymode_trim_whitespaces = orig_trim_whitespaces
  else
    unlet g:pymode_trim_whitespaces
  endif
endfunction

command! -nargs=* -complete=file -bang MyRename call MyRename(<q-args>, '<bang>')

You've also indicated that you're happy to edit the code of vim-rename, so an even quicker (but even more hacky) fix would be simply to add the lines that set and reset g:pymode_trim_whitespaces at appropriate places in the Rename() function itself. (i.e. just before and after the line that performs the rename (silent! exe 'saveas' . a:bang . ' ' . l:name).