Is 'source'-ing a vim file simlar to 'include' in other languages?

Question

When a vim file is source-ed is it like including the raw text of the file into the current script is it more like executing its contents and returning to the current file?

Answer 1

Different languages have different semantics for this, so I won't compare, but source in Vim is not exactly like either.

For one, Vim has script-local variables, which, in practice, mean file-local.

Take these examples:

foo.vim (practically lifted as-is from :h script-variable):

let s:counter = 0
function! StartCounting(incr)
    if a:incr
        function MyCounter()
            let s:counter = s:counter + 1
        endfunction
    else
        function MyCounter()
            let s:counter = s:counter - 1
        endfunction
    endif
endfunction
let b:bar=2

bar.vim:

let b:bar=1
source foo.vim
call StartCounting(1)
echo s:counter
echo b:bar

• If it were simply including the raw text, I'd expect to see s:counter have a non-zero value.
• If it were executing the contents and returning, I'd expect to see b:bar unchanged.

Instead, the output is:

Error detected while processing /tmp/bar.vim:
line    4:
E121: Undefined variable: s:counter
E15: Invalid expression: s:counter
2

So b:bar is changed by the sourced file, but a script-local variable defined in the sourced file is not directly accessible by the calling file.