How do I move vertically until reaching a non-whitespace character?

Question

In a very long file with (accurately-) indented code, it may be helpful to move directly to a line of text above or below the cursor which delimits the indenting.

(One way of doing this could be via the indent foldmethod, by folding the current indent level, which collapses the lines delimiting the indent level to be only a j or k away from the cursor. However, I have found instances where indent folding hasn't been able to work on the indent I'm interested in.)

Here's an example, with the cursor marked by the underscore _ (at the second character column between the definitions of class Bazz and class Qux), but imagine that the number of paragraphs or lines within the modules is unknown or variable:

module Foo
  # lots of code...
end

module Bar
  class Baz
    # ...
  end

  class Bazz
    # lots of code...
  end
 _
  class Qux
    # ...
  end

  class Quux
    # lots of code...
  end
end

...how could I quickly navigate to the o of module Bar above the cursor, or the n of the end below the cursor at the very last line? Note that the vertical column contains whitespaces, but also no characters at the second column in between the class definitions.

Answer 1

How about this function?

function FloatUp()
    while line(".") > 1
                \ && (strlen(getline(".")) < col(".")
                \ || getline(".")[col(".") - 1] =~ '\s')
        norm k
    endwhile
endfunction

You could nnoremap gU :call FloatUp()<CR> (gU for "go up"), and then invoke with gU.

Here's an explanation:

• The code repeatedly moves up the cursor (with norm k) as long as the while condition holds.
• The while condition holds if this is not the first line (line(".") > 1) and either
  • this line is too short (probably empty); or
  • the current line (getline("."))'s character at the current column ([col(".") - 1]) is whitespace (=~ '\s'; i.e., matches the whitespace pattern).

Answer 2

I like using search for these things, because Vim's regexs have an insane amount of things you can search for, like specific virtual column numbers, in this case:

nnoremap cd /\%<C-R>=virtcol(".")<CR>v\S<CR>

nnoremap cu ?\%<C-R>=virtcol(".")<CR>v\S<CR>

Use cd to go down and cu to go up. I'm thinking "column up" and "column down" here. I'm almost 100% confident that these are no-ops by default. Or pick your own mappings.

This should work whether you are using tabs or spaces or both.

Answer 3

You may use JumpToVerticalOccurrence plugin (default mapped to ]| and [|). There are few others like ]V{char} which works like f, but vertically. You can of course remap them as required.

---

If you don't want to use plugins, you may try to use :search with virtcol(.), e.g.:

:call search('\%' . virtcol('.') . 'v\S', 'bW')

where:

• virtcol('.') gives you the current column,
• \S stands for non-whitespace
• bW is for backward search

Check :help search to learn more.

To make it easier to use, you can map it, e.g.:

:map <C-k> :call search('\%' . virtcol('.') . 'v\S', 'bW')<CR>
:map <C-j> :call search('\%' . virtcol('.') . 'v\S', 'W')<CR>

---

Alternatively, if your code contains brackets, use % to jump between matching them (e.g. {, }, [, ], etc.) or use whole paragraph jumps ({, } with Shift if necessary).

---

Links/sources:

• Move to the next row which has non-white space character in the same column in vim? at stackoverflow

Answer 4

I use a modified version of the vim-indent-object plugin to provide this behavior. My modifications can be seen here.

This allows me to map [i to go to beginning of current indent level and ]i to go the end.

Answer 5

Since I don't see it here as an answer (edit just noticed that superjer mentioned something very similar). You can simply the / or ? search.

For example, you can search downward for a non whitespace character in the 2nd column like this:

/\%2v\S

The breakdown is:

/    "search downward (use ? for upward movement)
\%2v "for the following char in the 2nd virtual column
\S   "any non white space character

Then you can use the normal operators to repeat the search.

For more info on the subject see :help \%c and :help \%v.

Answer 6

It's not exactly what you asked for because it's not vertical movement, but something that's similar, fast, and might be good enough for you is moving backward 2 paragraphs: {{. This will take you to the line right before module Bar.

Answer 7

jeetsukumaran/vim-indentwise works well for relative, absolute, or block-scope movements across indented blocks.

Answer 8

I use my own plugin move_until_char_changes.vim for that.

I map it to gK and gJ.

It will jump over many lines with the same character in the current column (not just whitespace), which can be useful in logfiles or SQL dumps with repeated strings.

By default it first moves one line, before picking up the "search" character.

It works in Visual mode provided you don't try to use it twice, and you aren't in linewise or blockwise Visual mode... (fixes welcome!)