How can I chain multiple commands in one mapping?

Question

These two mappings work separately:

nnoremap <leader>zs :let @+=substitute(substitute(join(filter(getline(1,'$'),'v:val=~"^source:"'),"\n"),'^\(source:\s*\)\(.*\)$','\2',''),'^\s*\(.*\)$','\1','')<CR><ESC>
nnoremap <leader>zd :let @+=getline('.')<CR>

Note on what the codes need to accomplish: the first mapping copies into system clipboard the text following "source: "; the second mapping copies the currently cursored line into system clipboard. I use a clipboard manager (Parcellite) thus I prefer to copy multiple items (separately) from a text file into clipboard.

How do I combine them into a single mapping?

I've tried following this answer to produce:

nnoremap <leader>zs :let @+=substitute(substitute(join(filter(getline(1,'$'),'v:val=~"^source:"'),"\n"),'^\(source:\s*\)\(.*\)$','\2',''),'^\s*\(.*\)$','\1','') \| let @+=getline('.')<CR>

but this doesn't work. What could I be doing wrong?

[UPDATE]

To illustrate, here is a sample text showing [*] where the cursor is currently in:

Her research also shows about 14% of adults are clinically addicted to food, predominantly ultraprocessed foods with higher levels of sugar, salt, fat and additives.

For comparison, 10.5% of Americans age 12 or older were diagnosed with alcohol use disorder in 2022, according to the National Survey on Drug Use and Health. [*]

While many people addicted to food will say that their symptoms began to worsen significantly in adolescence, some recall a childhood focused on ultraprocessed food.

source: https://edition.cnn.com/2024/06/27/health/child-addiction-ultraprocessed-foods-wellness/index.html

After pressing <leader>zs in vim, parcellite should show this when accessed:

Answer 1

What could I be doing wrong?

Inventing terminology would be one thing: "leader command" and "leader entries" are meaningless, for example.

Focusing on irrelevant details would be another: the "leader" mechanism is totally irrelevant.

And cramming too much functionality into a one-liner would be yet another.

First, let's clean up your original mappings:

nnoremap <leader>zs <Cmd>let @+ =substitute(substitute(join(filter(getline(1,'$'),'v:val=~"^source:"'),"\n"),'^\(source:\s*\)\(.*\)$','\2',''),'^\s*\(.*\)$','\1','')<CR>
nnoremap <leader>zd <Cmd>let @+ =getline('.')<CR>

and make <leader>zs more palatable:

function! GetTextFollowingSource()
    return getline(1, '$')
        \ ->filter('v:val=~"^source:"')
        \ ->join("\n")
        \ ->substitute('^\(source:\s*\)\(.*\)$','\2','')
        \ ->substitute('^\s*\(.*\)$','\1','')
endfunction
nnoremap <leader>zs <Cmd>let @+ = GetTextFollowingSource()<CR>
nnoremap <leader>zd <Cmd>let @+ = getline('.')<CR>

Now, in theory, you should be able to combine them like this:

nmap <key> <leader>zs<leader>zd

or like this:

nnoremap <key> <Cmd>let @+ = GetTextFollowingSource()<CR><Cmd>let @+ = getline('.')<CR>

which should have the same outcome.

They do, actually, but only if you use internal registers:

nnoremap <leader>zs <Cmd>let @a = GetTextFollowingSource()<CR>
nnoremap <leader>zd <Cmd>let @b = getline('.')<CR>

which gives you the "text following source" in register a and the current line in register b. So the problem is elsewhere.

Your assessment that there might be a timing issue can be tested easily outside of your specific mappings with the following command:

:let @+ = 1|let @+ = 2|let @+ = 3

which, in my clipboard manager (not Parcellite), gives me this:

which points to only the last invocation having any effect.

Adding delay:

:let @+ = 1|sleep 1|let @+ = 2|sleep 1|let @+ = 3

seems to help, here:

Applied to the case at hand:

nmap <key> <leader>zsgs<leader>zd

I get this, which I think is the desired outcome:

It also works with the other method:

nnoremap <key> <Cmd>let @+ = GetTextFollowingSource()<CR>gs<Cmd>let @+ = getline('.')<CR>

Now, which method to choose?

The first one is short and sweet, but:

• the three parts of the RHS (<leader>zs, gs, and <leader>zd) are not clearly delimited, which impacts readability,
• the value of :help mapleader can be changed between two <leader> expansions so this <leader> might not be the one used for the original mappings.

The second one is easier to follow and immune to <leader> shadowing, but it is starting to become too long for my taste. YMMV.

If you want to keep the original individual mappings, then both methods are fine.

If you don't care about the original individual mappings, then the second method might be better but, at this point, why not use a single easy-to-follow function?

function! ExtractLineAndSource()
    let @+ = getline(1, '$')
        \ ->filter('v:val=~"^source:"')
        \ ->join("\n")
        \ ->substitute('^\(source:\s*\)\(.*\)$','\2','')
        \ ->substitute('^\s*\(.*\)$','\1','')
    sleep
    let @+ = getline('.')
endfunction
nnoremap <key> <Cmd>call ExtractLineAndSource()<CR>