How can I change this comment plugin to work at the start of the line?

Question

I got this from voyeg3r's gist He and @dave-kennedy made it 3 years ago. I am here because I couldn't contact them

Can someone help me add a feature such that this vimscript code puts comment out signs at the first of each line?

let s:comment_map = {
    \   "c": '\/\/',
    \   "cpp": '\/\/',
    \   "go": '\/\/',
    \   "java": '\/\/',
    \   "javascript": '\/\/',
    \   "lua": '--',
    \   "scala": '\/\/',
    \   "php": '\/\/',
    \   "python": '#',
    \   "ruby": '#',
    \   "rust": '\/\/',
    \   "sh": '#',
    \   "desktop": '#',
    \   "fstab": '#',
    \   "conf": '#',
    \   "profile": '#',
    \   "bashrc": '#',
    \   "bash_profile": '#',
    \   "mail": '>',
    \   "eml": '>',
    \   "bat": 'REM',
    \   "ahk": ';',
    \   "vim": '"',
    \   "tex": '%',
    \ }

function! ToggleComment()
    if has_key(s:comment_map, &filetype)
        let comment_leader = s:comment_map[&filetype]
        if getline('.') =~ '^\s*$'
            " Skip empty line
            return
        endif
        if getline('.') =~ '^\s*' . comment_leader
            " Uncomment the line
            execute 'silent s/\v\s*\zs' . comment_leader . '\s*\ze//'
        else
            " Comment the line
            execute 'silent s/\v^(\s*)/\1' . comment_leader . ' /'
        endif
    else
        echo "No comment leader found for filetype"
    endif
endfunction

nnoremap <Leader>t :call ToggleComment()<CR>
vnoremap <Leader>t :call ToggleComment()<CR>

PS: this works perfectly. But i need the extra feature which will put comment out signs at the first of each line

for example: if i comment out this code

     #include <iostream>
using namespace std;

                          int main() {
    cout << "hello world" << "\n";
             }

it will be like this

//     #include <iostream>
//using namespace std;

//                          int main() {
//    cout << "hello world" << "\n";
//             }

Answer 1

I think you need to change

            " Comment the line
            execute 'silent s/\v^(\s*)/\1' . comment_leader . ' /'

to

            " Comment the line
            execute 'silent s/^/\1' . comment_leader . '/'

so that it substitutes at the beginning of the line rather than after any space. The uncomment pattern needs similar modifications: replace \v\s*\zs with ^, and remove \s*\ze entirely.

---

For extra niceness, use escape(comment_leader, '/\') in the substitute commands; then the configuration doesn't need to escape the slashes.

Answer 2

It might be worth a mention that you can also visually select the lines and then do:

:'<,'>norm I// 

to apply the normal mode command Insert at the start of the line the commenting out characters (and remember to put a space after: // )

Without visual selection you could use line addresses:

" comment lines 10 through 20 
:10,20norm I// 

" comment relative lines -10 through +20
:-10,+20norm I//