How do I have buffers listed in a quickfix window in Vim?

Question

Using vim editor, a common task is to browse buffers. I now use standard commands like :ls or a :bnext. In fact I set in my .vimrc:

"move amongs buffers with CTRL
map <C-J> :bnext<CR>
map <C-K> :bprev<CR>

I would like to browse buffers as list in quickfix window, in the simple (=excellent) way MRU plugin implements.

Is there a plugin as simple as MRU but acting on buffers ?

OK, a possible solution could be to use :CtrlpBuffers command, part of Ctrlp plugin but I'm not a big fan of Ctrlp, because sometime have strange beahviours I do not fully understand (the fuzzy-mode selections...); so I'm look for something really simple as MRU plugin.

BTW, I joked with :cexpr {expr} command, trying populate the quickfix windows with content of :buffers list, without success (maybe because my ignorance programming vimscripts)

Any suggestion ?

Answer 1

You can populate the quickfix list with each buffer like this:

:call setqflist(map(filter(range(1, bufnr('$')), 'buflisted(v:val)'), '{"bufnr": v:val}'))

• setqflist() takes a List of Dictionary items describing each error (filename, line number, position, etc.). In this case we're specifying a minimal set of information: the buffer number
• map() takes a List and an expression (a string) and returns a new List of the expression applied to each item of the input List. Here, we're taking a List of listed buffer numbers and formatting them for use in setqflist() ('{"bufnr": v:val}', where v:val is the value of the item in the list)
• filter() filters a List, removing elements that don't satisfy a given expression. Here the expression is buflisted(v:val), meaning the buffer number exists and is listed, i.e. appears in :ls output
• range(a, b) generates a List of numbers from a to b
• bufnr() returns the number of a given buffer name. If the argument is '$', it returns the highest buffer number

That's a lot to type, and not very memorable, so you can wrap it in a command in your vimrc:

command! Qbuffers call setqflist(map(filter(range(1, bufnr('$')), 'buflisted(v:val)'), '{"bufnr":v:val}'))

Now you can just use :Qbuffers to populate the quickfix list.

---

If you want this to be updated automatically as new buffers are added, you can do something like this:

autocmd BufAdd * Qbuffers

I wouldn't recommend this, however, as it will render the quickfix list pretty unusable for things like :make or :grep.

Answer 2

You should try this mapping:

nnoremap gb :ls<CR>:b<Space>

At the prompt, type the desired buffer number and hit Enter.

Answer 3

Have a look at the bufexplorer plugin. It opens a browsable list of all buffers in a sidebar, similar to the mentioned MRU plugin. Also, there are several more such plugins on vim.org.

PS: You've asked the same question on Stack Overflow; please don't submit the identical question to multiple sites in parallel!

Answer 4

If you are using a fairly recent version of Vim, you can use the following script. This script displays only the buffer name in the quickfix window, reuses the same quickfix list for listing the buffers (avoids polluting the quickfix stack with too many quickfix lists), sorts the buffers by their last used timestamp and refreshes the quickfix window only if it is open.

Modified: Updated to handle the strict buffer checking added recently to Vim.

func s:QfBufferName(info)
  let items = getqflist(#{id: a:info.id, items: v:true}).items
  return items->map('bufname(v:val.bufnr)')
endfunc

let s:qfID = 0
let s:qbuflistNeedUpdate = v:false

func s:qbuffer(update) abort
  let s:qbuflistNeedUpdate = v:false
  let bufs = getbufinfo(#{buflisted: v:true})
  let bufs = bufs->sort({a, b -> a.lastused < b.lastused})
  let bufs = bufs->filter('v:val.name != ""')
  let items = map(bufs, '{"bufnr": v:val.bufnr}')

  let s:qfID = getqflist(#{id: s:qfID}).id
  let d = #{items: items, quickfixtextfunc: 's:QfBufferName'}
  if s:qfID != 0
    let d['id'] = s:qfID
  endif
  call setqflist([], 'r', d)
  if !a:update
    copen
  endif
endfunc

command! Qbuffers call s:qbuffer(v:false)
augroup Qbuffer
  au!
  au BufEnter * let s:qbuflistNeedUpdate = v:true
  au SafeState * if s:qbuflistNeedUpdate | call <SID>qbuffer(v:true) | endif
augroup END