How to pass v:register to custom operator when working on custom text object?

Question

I have a simple custom operator, it echoes v:register, it's mapped to ,f. After reading this, i creat it like this :

function! s:foo(type,...)
  echo v:register
endfunction

function! s:setupOpfunc(func)
  let &opfunc = a:func
  return 'g@'
endfunction

nnoremap <expr> ,f <sid>setupOpfunc('<sid>foo')

It wors fine on built in textobjects, e.g. "x,faw output

x

But it doesn't work on custom textobject. Assume i have this simple custom text object:

vnoremap ix iw

" I know you can map to `iw` directly, but that's not the point of this problem.
onoremap ix :normal vix<cr>

"x,fix output

"

I think it doesn't work because :normal ... erased v:resiter. I tried to use onoremap <expr> ... to create omap for textobject, but :h map-expression says :normal( needed to visually select text object ) is blocked during it's expression evaluation.

Built in operator has no this kind of problem "xyix happily copy word into register x.

One crude way i know to make this work is to use some global variable:

function! s:setupOpfunc(func)
  let g:__opfunc_rgister = v:register
  ...
endfunction

But it doesn't feel right, are there any other ways to make this work?

Answer 1

Consider if you were doing some operation in visual mode for deleting in a word, you would use the following to put the deletion in register a.

viw"ad      ->   v        [iw]      ["a]       d
                 visual   object    register   operator

Similarly, placing "a in the omap after the operator ix passes it to the opfunc. Either of these alternatives seems to work:

onoremap ix :normal vix"<c-r>=v:register<cr><cr>

onoremap <expr> ix ':normal vix"'.v:register.'<cr>'

At the point of creation of the normal string, v:register is set correctly.

I think this is a general principle. If you make an omap that uses visual mode, you should save and append the register invocation for the sake of any following opfuncs

func! MyOmap()
    let l:reg = v:register
    normal! vaw
    execute 'normal! "' . l:reg 
endfunc

All that being said, custom text objects do work built-in operators without this extra work, so maybe vim should be fixed do the right thing here, with custom op + custom object.