How to remove trailing white-spaces automatically while typing?

Question

I'm often editing code where others didn't care about trailing white-spaces. I'm using the TrimWhiteSpace()-function from this answer to remove white-spaces when saving the file.

However that leaves me with changes all other the file and VCS gives me many unrelated changes to revert or to commit.

Ideally I would like to automatically strip trailing white-spaces of every line I pressed ENTER while being in insert-mode. At least I think this is what I need.

How can I achieve this? Googling for some seconds did not bring up anything (not even on this site).

Answer 1

I'd do it with an autocommand that fires whenever you leave insert mode:

function! PreciseTrimWhiteSpace()
  " We need to save the view because the substitute command might
  " or might not move the cursor, depending on whether it finds
  " any whitespace.
  let saved_view = winsaveview()

  " Remove white space. Ignore "not found" errors. Don't change jumplist.
  keepjumps '[,']s/\s\+$//e

  " Move cursor back if necessary.
  call winrestview(saved_view)
endfunction

augroup PreciseTrimWhiteSpace
  autocmd!
  autocmd InsertLeave * call PreciseTrimWhiteSpace()
augroup end

This performs a substitute command using the range of lines between the '[ and '] marks: i.e. it removes whitespace that was introduced by the most recent insert.

To me, this seems more elegant than using an insert mapping, (but others may disagree).

For more details, see:

• :help InsertLeave
• :help ranges
• :help :s_flags
• :help :keepjumps
• :help '[

Answer 2

I think someone is probably going to shoot me for this monstrosity. However:

inoremap <CR> <Esc>g_lDo

This maps insert mode Enter to:

• <Esc>: return to normal mode
• g_: move to last non-blank character in line
• l: move one character to the right
• D: delete to end of line
• o: move to the next line, returning to insert mode

While I guess this accomplishes what you describe, I suspect there's a case I haven't thought of which will produce weird and wonderful behaviour! It could also prove quite nasty for any file types where whitespace is important or required.

As you note, there are tools out there which strip whitespace from end of line on save. For completeness, I'll mention that the Vim Wikia describes a number of them, this for example:

" Strip line endings for certain filetypes
autocmd FileType c,cpp,java,php autocmd BufWritePre <buffer> %s/\s\+$//e

Answer 3

I'd count the number of space characters before the cursor at the moment <cr> is hit and produce as many <BS>. It can be done with substitute:

:inoremap <expr> <cr> substitute(matchstr(getline('.')[: col('.')-2], '\S\zs\s*$'), '.', "<bs>", 'g')."<cr>"

or with repeat+len:

:inoremap <expr> <cr> repeat("<bs>", len(matchstr(getline('.')[: col('.')-2], '\S\zs\s*$')))."<cr>"

Notes:

• As there is no movement/break (with <esc>) in the flow of this solution, anything that is typed can be undone, redone , etc. However, if you start a new insert sequence to cut after a series of spaces, redoing the same insertion sequence with . elsewhere is likely to remove too many characters.
• The \S\zs is a workaround when we're on en empty line and when each <BS> deletes &sw characters. In that case I should check getline() result and do something smarter.

A version that behaves a little bit better regarding indented empty lines is the following:

function! s:trim_ws_on_the_fly()
  let line = getline('.')
  " TODO: set and reset &bs
  if line =~ '^\s*$'
    let nb = (virtcol('.') + 2*&sw-2) / &sw - 1
    " echomsg "remove "virtcol('.').'/'.&sw.' -> '.nb
  else
    let nb = len(matchstr(line[: col('.')-2], '\s*$'))
    let line = ''
  endif
  return repeat("\<bs>", nb)."\<cr>".line
endfunction
inoremap <expr> <cr> <sid>trim_ws_on_the_fly()