Set line numbers based on line count

Question

If a file has a large number of lines, I'd like to enable line numbers, otherwise leave them off by default. If I run the command:

if line('$') > 150 | :set number | endif

while vim is open, file lines are enabled/unchanged as expected. Putting this line into my init.vim (for neovim) has no effect. What am I doing incorrectly? Thanks!

Answer 1

Scripts in your init.vim are only executed when you first launch Neovim, or when you source the file manually (same goes for vimrc and vim).

To trigger a script automatically, based on an event, you can use an autocommand.

For your case, this should do the trick:

augroup ShowLineNumberForLongFiles
  autocmd!
  autocmd BufEnter * if line('$') > 150 | setlocal number | endif
augroup END

This will execute your script whenever you enter a new buffer. The first line of the group (autocmd!) is there to clear the group content. This helps to avoid piling up scripts if you ever source your config file manually.

Notice I change set to setlocal to make sure the option is only applied to the current buffer.

Here are some related help topics you can read for deeper explanations:

• :h autocommand
• :h :autocmd
• :h BufEnter
• :h augroup
• :h :source
• :h set
• :h setlocal

Answer 2

An auto command is appropriate here...

autocmd BufReadPost * if line('$') > 150 | :setlocal number | else | :setlocal nonumber | endif

OR, you can use this nice enhancement care of MartinTournoij. It has the same result but takes up a lot less space:

autocmd BufReadPost * let &l:number = line('$') > 150

Explanation: First, &l:number is a synonym, if you will, of the setting altered by setlocal number. The conditional line('$') > 150 returns, essentially, either true or false. Since 'number' should be set to true or false also we can just do a direct assignment to it from the conditional result let &l:number = ....

Either way, this autocommand approach accomplishes a few things...

1. Ensures a check is made after any buffer is loaded (when number of lines is known!).
2. Uses the buffer-specific setting rather than the global setting.
3. Explicitly enables or disables as appropriate to ensure correct setting.

Note that if a file has a modeline that sets/unsets line numbers that has priority and will override this.

If you've not used auto commands before they usually go in your init.vim file. You should enclose them in an auto command group like this...

augroup InitVimAutocmds
   au!
   [auto commands go here]
augroup END

This ensures they don't get entered multiple times if you reload init.vim.

Update: I don't know if you were thinking about this but it's worth pointing out (another nod to MartinTournoij) that this is static, i.e. the line numbering is determined upon buffer load and if you subsequently surpass or drop below 150 lines nothing will change. It is definitely possible to extend this so it's dynamic. If that's something you're interested in let me know.